7. fejezet - Kivételkezelés

1. példa

DECLARE
  i PLS_INTEGER;
  j NUMBER NOT NULL := 1;

  /* Egy névtelen hiba nevesítése. */
  numeric_overflow EXCEPTION;
  PRAGMA EXCEPTION_INIT(numeric_overflow, -1426); -- numeric overflow

  /* Egy már amúgy is nevesített kivételhez még egy név rendelése. */
  VE_szinonima EXCEPTION;
  PRAGMA EXCEPTION_INIT(VE_szinonima, -6502); -- VALUE_ERROR
BEGIN
  /* Kezeljük a numeric overflow hibát, PL/SQL-ben ehhez
  a hibához nincs előre definiálva kivételnév. */
  <<blokk1>>
  BEGIN
  i := 2**32;
  EXCEPTION
    WHEN numeric_overflow THEN
      DBMS_OUTPUT.PUT_LINE('Blokk1 - numeric_overflow! ' || SQLERRM);
  END blokk1;
  /* A VE_szinonima használható VALUE_ERROR helyett. */
  <<blokk2>>
  BEGIN
  i := NULL;
  j := i; -- VALUE_ERROR-t vált ki, mert i NULL.
  DBMS_OUTPUT.PUT_LINE(j);
  EXCEPTION
    WHEN VE_szinonima THEN
      DBMS_OUTPUT.PUT_LINE('Blokk2 - VALUE_ERROR: ' || SQLERRM);
  END blokk2;
  /* A VALUE_ERROR is használható VE_szinonima helyett. A két kivétel megegyezik. */
  <<blokk2>>
  BEGIN
  RAISE VE_szinonima;
  EXCEPTION
    WHEN VALUE_ERROR THEN -- A saját kivételünk szinonima a VALUE_ERROR-ra
      DBMS_OUTPUT.PUT_LINE('Blokk3 - VALUE_ERROR: ' || SQLERRM);
  END blokk1;
END;
/

A PL/SQL eljárás sikeresen befejeződött.
*/

2. példa

DECLARE
  a NUMBER NOT NULL := 1;
  b NUMBER;
BEGIN
  <<tartalmazo>>
  BEGIN
  <<vissza>>
    a := b; -- VALUE_ERROR-t vált ki, mert b NULL
  EXCEPTION
  WHEN VALUE_ERROR THEN
    b := 1; -- Hogy legközelebb b ne legyen NULL;
    -- GOTO vissza; -- fordítási hibát eredményezne
    GOTO tartalmazo; -- külső blokk cimkéjére ugorhatunk
  END;
END;
/

3. példa

BEGIN
  DECLARE
    /* A következő változó inicializációja során
    VALUE_ERROR kivétel váltódik ki. */
    i NUMBER(5) := 123456;
  BEGIN
    NULL;
  EXCEPTION
    WHEN VALUE_ERROR THEN
      /* Ez a kezelő nem tudja elkapni a deklarációs
      részben bekövetkezett kivételt. */
      DBMS_OUTPUT.PUT_LINE('belső');
  END;
EXCEPTION
  WHEN VALUE_ERROR THEN
    /* Ez a kezelő kapja el a kivételt. */
    DBMS_OUTPUT.PUT_LINE('külső');
END;
/

A PL/SQL eljárás sikeresen befejeződött.
*/

4. példa

DECLARE
  hibas_argumentum EXCEPTION;
  v_Datum DATE;
  /*
  Megnöveli p_Datum-ot a második p_Ido-vel, aminek a mértékegységét
  p_Egyseg tartalmazza. Ezek értéke perc', 'óra', 'nap', 'hónap' egyike lehet.
  Ha hibás a mértékegység, akkor hibas_argumentum kivétel váltódik ki.
  */
  FUNCTION hozzaad(p_Datum DATE, p_Ido NUMBER, p_Egyseg VARCHAR2) RETURN DATE IS
    rv DATE;
  BEGIN
    CASE p_Egyseg
      WHEN 'perc' THEN
        rv := p_Datum + p_Ido/(24*60);
      WHEN 'óra' THEN
        rv := p_Datum + p_Ido/24;
      WHEN 'nap' THEN
        rv := p_Datum + p_Ido;
      WHEN 'hónap' THEN
        rv := ADD_MONTHS(p_Datum, p_Ido);
      ELSE
        RAISE hibas_argumentum;
    END CASE;
    RETURN rv;
  END hozzaad;
  /* Ez a függvény hibás mértékegység esetén nem vált ki
  kivételt, hanem NULL-t ad vissza. */
  FUNCTION hozzaad2(p_Datum DATE, p_Ido NUMBER, p_Egyseg VARCHAR2) RETURN DATE IS
    rv DATE;
  BEGIN
    RETURN hozzaad(p_Datum, p_Ido, p_Egyseg);
  EXCEPTION
    WHEN hibas_argumentum THEN
      RETURN NULL;
  END hozzaad2;
BEGIN
  <<blokk1>>
  BEGIN
    v_Datum := hozzaad(SYSDATE, 1, 'kiskutyafüle');
  EXCEPTION
    WHEN hibas_argumentum THEN
      DBMS_OUTPUT.PUT_LINE('Blokk1 - hibás argumentum: '
        || SQLCODE || ', ' || SQLERRM);
  END blokk1;
  <<blokk2>>
  BEGIN
    v_Datum := hozzaad2(SYSDATE, 1, 'kiskutyafüle');
    DBMS_OUTPUT.PUT_LINE('Blokk2 - nincs kivétel.');
  EXCEPTION
    WHEN OTHERS THEN
      DBMS_OUTPUT.PUT_LINE('Blokk2 - hiba: '
        || SQLCODE || ', ' || SQLERRM);
      RAISE; -- A hiba továbbadása külső irányba.
  END blokk2;
END;
/

A PL/SQL eljárás sikeresen befejeződött.
*/

5. példa

DECLARE
  SUBTYPE t_ugyfelrec IS ugyfel%ROWTYPE;
  v_Ugyfel t_ugyfelrec;
  v_Nev VARCHAR2(10);
  /* A függvény megadja az adott keresztnevű ügyfél adatait.
  Ha nem egyértelmű a kérdés, akkor ezt kivétellel jelzi. */
  FUNCTION ugyfel_nevhez(p_Keresztnev VARCHAR2) RETURN t_ugyfelrec IS
    v_Ugyfel t_ugyfelrec;
  BEGIN
    SELECT * INTO v_Ugyfel FROM ugyfel
    WHERE UPPER(nev) LIKE '% %' || UPPER(p_Keresztnev) || '%';
    RETURN v_Ugyfel;
  EXCEPTION
    /* Egy WHEN ág több nevesített kivételt is kezelhet. */
    WHEN NO_DATA_FOUND OR TOO_MANY_ROWS THEN
      RAISE_APPLICATION_ERROR(-20010,
        'A keresett ügyfél nem vagy nem egyértelműen létezik');
  END ugyfel_nevhez;
BEGIN
  FOR i IN 1..3 LOOP
    CASE i
      WHEN 1 THEN v_Nev := 'Máté'; -- Egy Máté van a könyvtárban.
      WHEN 2 THEN v_Nev := 'István'; -- Több István is van.
      WHEN 3 THEN v_Nev := 'Gergő'; -- Nincs Gergő nálunk.
    END CASE;
  <<blokk1>>
    BEGIN
      DBMS_OUTPUT.PUT_LINE(i || '. Keresett név: "' || v_Nev || '".');
      v_Ugyfel := ugyfel_nevhez(v_Nev);
      DBMS_OUTPUT.PUT_LINE('Nincs hiba, ügyfél: ' || v_Ugyfel.nev);
    EXCEPTION
      /* Csak a WHEN OTHERS ág tudja elkapni a névtelen kivételeket. */
      WHEN OTHERS THEN
        DBMS_OUTPUT.PUT_LINE('Hiba: ' || SQLCODE || ', ' || SQLERRM);
    END blokk1;
  END LOOP;
  /* A felhasználói hiba számához is rendelhetünk kivételt. */
  <<blokk2>>
  DECLARE
    hibas_ugyfelnev EXCEPTION;
    PRAGMA EXCEPTION_INIT(hibas_ugyfelnev, -20010);
  BEGIN
    DBMS_OUTPUT.NEW_LINE;
    DBMS_OUTPUT.PUT_LINE('Blokk2 - Szilveszter van-e?');
    v_Ugyfel := ugyfel_nevhez('Szilveszter'); -- Persze nincs.
    DBMS_OUTPUT.PUT_LINE('Igen van: ' || v_Ugyfel.nev);
  EXCEPTION
    WHEN hibas_ugyfelnev THEN
      DBMS_OUTPUT.PUT_LINE('Hiba: '
        || SQLCODE || ', ' || SQLERRM);
      RAISE; -- A hiba továbbadása
  END blokk2;
/* Mivel itt nincs kivételkezelő, a blokk2 kivételkezelőjéből
  továbbadott kivételt a futtató rendszer kezeli. */
END;
/

/*
Eredmény:
1. Keresett név: "Máté".
Nincs hiba, ügyfél: Szabó Máté István
2. Keresett név: "István".
Hiba: -20010, ORA-20010: A keresett ügyfél nem vagy nem egyértelműen létezik
3. Keresett név: "Gergő".
Hiba: -20010, ORA-20010: A keresett ügyfél nem vagy nem egyértelműen létezik

Blokk2 - Szilveszter van-e?
Hiba: -20010, ORA-20010: A keresett ügyfél nem vagy nem egyértelműen létezik

Hiba a(z) 1. sorban:
DECLARE
*
ORA-20010: A keresett ügyfél nem vagy nem egyértelműen létezik
ORA-06512: a(z) helyen a(z) 53. sornál
*/